4.35.3.2 Time and date predicates

get_time(-TimeStamp)

Return the current time as a TimeStamp. The granularity is system-dependent. See section 4.35.3.1.

stamp_date_time(+TimeStamp, -DateTime, +TimeZone)

Convert a TimeStamp to a DateTime in the given timezone. See section 4.35.3.1 for details on the data types. TimeZone describes the timezone for the conversion. It is one of local to extract the local time, ’UTC’ to extract a UTC time or an integer describing the seconds west of Greenwich.

date_time_stamp(+DateTime, -TimeStamp)

Compute the timestamp from a date/9 term. Values for month, day, hour, minute or second need not be normalized. This flexibility allows for easy computation of the time at any given number of these units from a given timestamp. Normalization can be achieved following this call with stamp_date_time/3. This example computes the date 200 days after 2006-07-14:

?- date_time_stamp(date(2006,7,214,0,0,0,0,-,-), Stamp),
   stamp_date_time(Stamp, D, 0),
   date_time_value(date, D, Date).
Date = date(2007, 1, 30)

When computing a time stamp from a local time specification, the UTC offset (arg 7), TZ (arg 8) and DST (arg 9) argument may be left unbound and are unified with the proper information. The example below, executed in Amsterdam, illustrates this behaviour. On the 25th of March at 01:00, DST does not apply. At 02.00, the clock is advanced by one hour and thus both 02:00 and 03:00 represent the same time stamp.

1 ?- date_time_stamp(date(2012,3,25,1,0,0,UTCOff,TZ,DST),
                     Stamp).
UTCOff = -3600,
TZ = 'CET',
DST = false,
Stamp = 1332633600.0.

2 ?- date_time_stamp(date(2012,3,25,2,0,0,UTCOff,TZ,DST),
                     Stamp).
UTCOff = -7200,
TZ = 'CEST',
DST = true,
Stamp = 1332637200.0.

3 ?- date_time_stamp(date(2012,3,25,3,0,0,UTCOff,TZ,DST),
                     Stamp).
UTCOff = -7200,
TZ = 'CEST',
DST = true,
Stamp = 1332637200.0.

Note that DST and offset calculation are based on the POSIX function mktime(). If mktime() returns an error, a representation_error dst is generated.

date_time_value(?Key, +DateTime, ?Value)

Extract values from a date/9 term. Provided keys are:

key	value
year	Calendar year as an integer
month	Calendar month as an integer 1..12
day	Calendar day as an integer 1..31
hour	Clock hour as an integer 0..23
minute	Clock minute as an integer 0..59
second	Clock second as a float 0.0..60.0
utc_offset	Offset to UTC in seconds (positive is west)
time_zone	Name of timezone; fails if unknown
daylight_saving	Bool (true) if dst is in effect
date	Term date(Y,M,D)
time	Term time(H,M,S)

format_time(+Out, +Format, +StampOrDateTime)

Modelled after POSIX strftime(), using GNU extensions. Out is a destination as specified with with_output_to/2. Format is an atom or string with the following conversions. Conversions start with a percent (%) character.^{150Descriptions taken from Linux Programmer's Manual} StampOrDateTime is either a numeric time-stamp, a term date(Y,M,D,H,M,S,O,TZ,DST) or a term date(Y,M,D).

• a
  The abbreviated weekday name according to the current locale. Use format_time/4 for POSIX locale.
• A
  The full weekday name according to the current locale. Use format_time/4 for POSIX locale.
• b
  The abbreviated month name according to the current locale. Use format_time/4 for POSIX locale.
• B
  The full month name according to the current locale. Use format_time/4 for POSIX locale.
• c
  The preferred date and time representation for the current locale.
• C
  The century number (year/100) as a 2-digit integer.
• d
  The day of the month as a decimal number (range 01 to 31).
• D
  Equivalent to %m/%d/%y. (For Americans only. Americans should note that in other countries %d/%m/%y is rather common. This means that in an international context this format is ambiguous and should not be used.)
• e
  Like %d, the day of the month as a decimal number, but a leading zero is replaced by a space.
• E
  Modifier. Not implemented.
• f
  Number of microseconds. The f can be prefixed by an integer to print the desired number of digits. E.g., %3f prints milliseconds. This format is not covered by any standard, but available with different format specifiers in various incarnations of the strftime() function.
• F
  Equivalent to %Y-%m-%d (the ISO 8601 date format).
• g
  Like %G, but without century, i.e., with a 2-digit year (00-99).
• G
  The ISO 8601 year with century as a decimal number. The 4-digit year corresponding to the ISO week number (see %V). This has the same format and value as %y, except that if the ISO week number belongs to the previous or next year, that year is used instead.
• V
  The ISO 8601:1988 week number of the current year as a decimal number, range 01 to 53, where week 1 is the first week that has at least 4 days in the current year, and with Monday as the first day of the week. See also %U and %W.
• h
  Equivalent to %b.
• H
  The hour as a decimal number using a 24-hour clock (range 00 to 23).
• I
  The hour as a decimal number using a 12-hour clock (range 01 to 12).
• j
  The day of the year as a decimal number (range 001 to 366).
• k
  The hour (24-hour clock) as a decimal number (range 0 to 23); single digits are preceded by a blank. (See also %H.)
• l
  The hour (12-hour clock) as a decimal number (range 1 to 12); single digits are preceded by a blank. (See also %I.)
• m
  The month as a decimal number (range 01 to 12).
• M
  The minute as a decimal number (range 00 to 59).
• n
  A newline character.
• O
  Modifier to select locale-specific output. Not implemented.
• p
  Either‘AM’or‘PM’according to the given time value, or the corresponding strings for the current locale. Noon is treated as‘pm’and midnight as‘am’.^{151Despite the above claim, some locales yield am or pm in lower case.}
• P
  Like %p but in lowercase:‘am’or‘pm’or a corresponding string for the current locale.
• r
  The time in a.m. or p.m. notation. In the POSIX locale this is equivalent to‘%I:%M:%S %p’.
• R
  The time in 24-hour notation (%H:%M). For a version including the seconds, see %T below.
• s
  The number of seconds since the Epoch, i.e., since 1970-01-01 00:00:00 UTC.
• S
  The second as a decimal number (range 00 to 60). (The range is up to 60 to allow for occasional leap seconds.)
• t
  A tab character.
• T
  The time in 24-hour notation (%H:%M:%S).
• u
  The day of the week as a decimal, range 1 to 7, Monday being 1. See also %w.
• U
  The week number of the current year as a decimal number, range 00 to 53, starting with the first Sunday as the first day of week 01. See also %V and %W.
• w
  The day of the week as a decimal, range 0 to 6, Sunday being 0. See also %u.
• W
  The week number of the current year as a decimal number, range 00 to 53, starting with the first Monday as the first day of week 01.
• x
  The preferred date representation for the current locale without the time.
• X
  The preferred time representation for the current locale without the date.
• y
  The year as a decimal number without a century (range 00 to 99).
• Y
  The year as a decimal number including the century.
• z
  The timezone as hour offset from GMT using the format HHmm. Required to emit RFC822-conforming dates (using ’%a, %d %b %Y %T %z’). Our implementation supports %:z, which modifies the output to HH:mm as required by XML-Schema. Note that both notations are valid in ISO 8601. The sequence %:z is compatible to the GNU date(1) command.
• Z
  The timezone or name or abbreviation.
• +
  The date and time in date(1) format.
• %
  A literal‘%’character.

The table below gives some format strings for popular time representations. RFC1123 is used by HTTP. The full implementation of http_timestamp/2 as available from library(http/http_header) is here.

http_timestamp(Time, Atom) :-
        stamp_date_time(Time, Date, 'UTC'),
        format_time(atom(Atom),
                    '%a, %d %b %Y %T GMT',
                    Date, posix).

Standard	Format string
xsd	’%FT%T%:z’
ISO8601	’%FT%T%z’
RFC822	’%a, %d %b %Y %T %z’
RFC1123	’%a, %d %b %Y %T GMT’

format_time(+Out, +Format, +StampOrDateTime, +Locale)

Format time given a specified Locale. This predicate is a work-around for lacking proper portable and thread-safe time and locale handling in current C libraries. In its current implementation the only value allowed for Locale is posix, which currently only modifies the behaviour of the a, A, b and B format specifiers. The predicate is used to be able to emit POSIX locale week and month names for emitting standardised time-stamps such as RFC1123.

parse_time(+Text, -Stamp)

Same as parse_time(Text, _Format, Stamp). See parse_time/3.

parse_time(+Text, ?Format, -Stamp)

Parse a textual time representation, producing a time-stamp. Supported formats for Text are in the table below. If the format is known, it may be given to reduce parse time and avoid ambiguities. Otherwise, Format is unified with the format encountered.

Name	Example
rfc_1123	Fri, 08 Dec 2006 15:29:44 GMT
	Fri, 08 Dec 2006 15:29:44 +0000
iso_8601	2006-12-08T17:29:44+02:00
	20061208T172944+0200
	2006-12-08T15:29Z
	2006-12-08
	20061208
	2006-12
	2006-W49-5
	2006-342

day_of_the_week(+Date,-DayOfTheWeek)

Computes the day of the week for a given date. Date = date(Year,Month,Day). Days of the week are numbered from one to seven: Monday = 1, Tuesday = 2, ... , Sunday = 7.